phpsh – phpcli开发的终极方案

最近用php代替vbs脚本,做些小工具的开发。为了方便测试不同php版本的兼容,专门写了一个 php版本切换的 批处理 phpsh.cmd,支持安装到系统、卸载等功能,还支持多个php版本的任意切换(需要先安装phpStudy)。

如果需要安装到系统,必须以管理员身份运行 命令提示符,基本的使用方法如下:

安装成功后,就不用使用管理员身份执行了。可以在任意目录 执行 phpsh,会自动设置php环境。

如果以 非管理员身份执行 安装和卸载,会有对应的提示。不安装到系统也可以运行:

不安装时,如果phpsh没有在当前路径,可以使用完整的路径名运行:

代码比较简单,下面时全部的代码:

@echo off

::安装路径
set ins=C:\Windows\%~nx0

::如果存在对应的PHP版本,进入主程序
if "%1"=="" goto main
if "%1"=="52" goto main
if "%1"=="53" goto main
if "%1"=="53n" goto main
if "%1"=="55" goto main
if "%1"=="55n" goto main
if "%1"=="70n" goto main
goto cmds

::主程序
:main
set PHP_VER=PHP%1
if "%PHP_VER%" == "PHP" set PHP_VER=PHP55
set path=d:\phpstudy\%PHP_VER%;%path%
title %PHP_VER%_sh
prompt %PHP_VER%_sh^>$p#
goto quit

::如果是输入的非数字参数,解析
:cmds
if "%1"=="/i" goto install
if "%1"=="/install" goto install
if "%1"=="/u" goto uninstall
if "%1"=="/uninstall" goto uninstall
if "%1"=="/v" goto version
if "%1"=="/version" goto version
goto help

::显示帮助
:help
echo 用法: %~n0 [/h ^| /help ^| /i ^| /install ^| /u ^| /unstall ^| /v ^| /version ^| PHP_VERSION]
echo.
echo   没有参数   设置php版本为php5.5
echo   /h         显示帮助
echo   /help      显示帮助,和/h相同
echo   /i         安装到系统
echo   /install   安装到系统,和/i相同
echo   /u         卸载
echo   /unstall   卸载,同/u
echo   /v         查看当前php版本
echo   /version   查看当前php版本,同/u
echo   52         设置php版本为php5.2
echo   53         设置php版本为php5.3
echo   53n        设置php版本为php5.3n
echo   55         设置php版本为php5.5
echo   55n        设置php版本为php5.5n
echo   70n        设置php版本为php7.0n
goto quit

::查看版本
:version
php --version
goto quit

::安装
:install
echo 开始安装..
if not exist %ins% copy %~f0 %ins%>nul
if %ERRORLEVEL% == 0 echo 安装成功,打开命令提示符后输入%~n0即可启动
if %ERRORLEVEL% == 1 echo 安装失败,必须以管理员模式运行
goto quit

::卸载失败
:uninstallerror
echo 卸载失败,必须以管理员模式运行
goto quit

::卸载
:uninstall
copy %~f0 %ins%.bak>nul
if %ERRORLEVEL% == 1 goto uninstallerror
echo 卸载成功
del %ins%.bak>nul
if exist %ins% del %ins%

:quit

发表评论

电子邮件地址不会被公开。 必填项已用*标注