set rs=conn.execute,set rs=server.createobject(“ADODB.recordset”)的若干谎言

经常用asp的同行,可能会建议用set rs=conn.execute(sql)来代替set rs=server.createobject(“ADODB.recordset”):rs.open conn,sql,1,1。还有一些同行更提出了用set rs=conn.execute(sql):res=rs.getRows(100)来优化ASP程序。其实在没有做此实验前,我也是很相信这种方法的。实际效果果真如此吗?经过一番测试,我发现结果远非如此,set rs=server.createobject(“ADODB.recordset”)的方法比set rs=conn.execute的方法快4~5倍。这个结果您信吗?不信,更我来一起做这个测试。猫七(苗启源)博客首发,转载请注明出处,原文地址: (http://www.miaoqiyuan.cn/p/conn-execute_rs-getrows)。

数据说明真相。首先创建一个多记录的数据库。

set conn=createobject("adodb.connection")
conn.open "provider=microsoft.jet.oledb.4.0;data source=E:\labs\miaoqiyuan.cn\g.mdb"
do while conn.execute("select count(id) from site")(0)<1000000
	conn.execute("insert into site(sitename,siteadmin,siteurl,sitekey) values('苗启源','http://localhost/app_login/','http://www.miaoqiyuan.cn','e10adc3949ba59abbe56e057f20f883e')")
loop

经过几个小时的运行,我得到了一个有63万多条记录的数据库。数据库大小为99.7MB(测试数据库下载地址http://www.miaoqiyuan.cn/products/rs-execute-test.rar)。

为了保证数据的真实性,我们用公共的头部header.asp来保存数据库连接字符串。footer.asp来保存运行时间。

运行环境,Windows 2003 Server SP2。IIS6.0,CPU E2200 2.2GHz,内存2Gx2。硬盘300G SATA+80G ATA。

公共头部:header.asp

< %
startTme=timer()
set conn=server.createobject("ADODB.connection")
conn.open "provider=microsoft.jet.oledb.4.0;data source="&server.mappath("g.mdb")
%>

公共底部:footer.asp

<hr />总共用时:< %=(timer()-startTme)*1000%>毫秒

测试方法:以三种方式,每页100条记录。同时读取第6000页到6099页的记录共一万条,并测出运行时间。

test1.asp,采用set rs=server.createobject(“ADODB.recordset”)的方法。


< %
for k=0 to 100
	response.write "<br /><br />第"&(6000+k)&"页<hr />"

	set rs=server.createobject("adodb.recordset")
	rs.open "select * from site",conn,1,1
	rs.pagesize=100
	rs.absolutepage=6000+k
	i=0
	do while not rs.eof and i<100
		i=i+1
		response.write rs("id")&":"&rs("sitename")&"<br />"&vbCrlf
		rs.movenext
	loop
	rs.close
	set rs=nothing

next
%>

test2.asp 采用set rs=conn.execute()的方法


< %
for k=0 to 100
	response.write "<br /><br />第"&(6000+k)&"页<hr />"

	set rs=conn.execute("select * from site")
	rs.movefirst
	rs.move (6000+k)*100
	i=0
	do while not rs.eof and i<100
		i=i+1
		response.write rs("id")&":"&rs("sitename")&"<br />"&vbCrlf
		rs.movenext
	loop
	rs.close
	set rs=nothing

next
%>

至于getRows,这种方法只能算是返回结果的优化,并不能算是一种方法。我们采用两种返回结果的方式测试。test3.asp采用set rs=server.createobject(“ADODB.recordset”)的方法,test4.asp采用set rs=conn.execute(sql)的方法


< %
for k=0 to 100
	response.write "<br /><br />第"&(6000+k)&"页<hr />"

	set rs=server.createobject("adodb.recordset")
	rs.open "select * from site",conn,1,1
	rs.pagesize=100
	rs.absolutepage=6000+k
	res=rs.getRows(100)
	rs.close
	set rs=nothing
	for i=0 to 99
		response.write res(0,i)&":"&res(1,i)&"<br />"&vbCrlf
	next

next
%>


< %
for k=0 to 100
	response.write "<br /><br />第"&(6000+k)&"页<hr />"

	set rs=conn.execute("select * from site")
	rs.movefirst
	rs.move (6000+k)*100
	res=rs.getRows(100)
	rs.close
	set rs=nothing
	for i=0 to 99
		response.write res(0,i)&":"&res(1,i)&"<br />"&vbCrlf
	next

next
%>

下面是我的测试结果:

test1.asp test2.asp test3.asp test4.asp
第一次测试 4281.25毫秒 20656.25毫秒 4281.25毫秒 18671.88毫秒
第二次测试 4234.375毫秒 25171.88毫秒 4312.5毫秒 13781.25毫秒
第三次测试 4328.125毫秒 20031.25毫秒 4234.375毫秒 19093.75毫秒

为什么会出现这种结果呢?set rs=conn.execute(sql),set rs=server.createobject(“ADODB.recordset”)为什么为相差这么多?对比一下test1.asp、test3.asp与test2.asp、test4.asp,除了返回结果的方式不同,还有一处就是rs.move。难道是这个原因?把test3.asp的代码稍微修改一下。存为test5.asp。


< %
for k=0 to 100
	response.write "<br /><br />第"&(6000+k)&"页<hr />"

	set rs=server.createobject("adodb.recordset")
	rs.open "select * from site",conn,1,1
	rs.movefirst
	rs.move (6000+k)*100
	res=rs.getRows(100)
	rs.close
	set rs=nothing
	for i=0 to 99
		response.write res(0,i)&":"&res(1,i)&"<br />"&vbCrlf
	next

next
%>

经过测试,test5.asp能比test3.asp快0.1~0.2秒,如果读取100条数据,这点差距可以忽略不计。

由此可见:set rs=conn.execute的方式确实比set rs=server.createobject(“ADODB.recordset”)方式慢,在学校的时候,老师教的一般都是set rs=server.createobject(“ADODB.recordset”)的方法,真正工作室,学习所谓的高手set rs=conn.execute优化的方法,结果最终发现,而鄙视用老师教的方法写程序的同行,最终发现还是老师教的速度快,而且set rs=server.createobject(“ADODB.recordset”)的方法比set rs=conn.execute的方法快4~5倍。囧。。。。猫七(苗启源)博客首发,转载请注明出处,原文地址: (http://www.miaoqiyuan.cn/p/conn-execute_rs-getrows)。

难道set rs=conn.execute就一无是处了吗?在数据插入方面,两者的差别有多大呢?详情请关注我的博客(http://www.miaoqiyuan.cn)今天太累了,就写这些吧~

set rs=conn.execute,set rs=server.createobject(“ADODB.recordset”)的若干谎言》上有2条评论

  1. None

    没有可比性,为什么非要比呢?
    set rs=conn.execute()
    rs.getrows()
    这种方法一般用在数据量少的情况下,比如说只有几十几百条数据的情况下,它只读一次数据库,然后把结果存入一个二维数组中,在这之后的操作就不需要数据库,而是直接对内存中的数据进行操作了,速度绝对比用常规方法快,而且也节省资源。而用常规方法的话,数据库操作得多少次?而在日常的情况下,一次读取大量数据的情况是很少的,所以在很多地方都提到使用上面这种方法,就是缘于此。
    还有上面比的分页,常规方法由于它自身的局限,对数据库的操作很费资源的,别说只是快那零点几秒,好的程序到最后拼的就是那零点几秒。
    高手总有他高的地方,不要随便就去b4人家。

发表评论

电子邮件地址不会被公开。 必填项已用*标注